apply plugin: "com.android.application"
apply plugin: "org.jetbrains.kotlin.android"
apply plugin: "com.facebook.react"
apply plugin: "app.accrescent.tools.bundletool"

/** 
 * This is the configuration block to customize your React Native Android app.
 * By default you don't need to apply any configuration, just uncomment the lines you need.
 */
react {
    /* Folders */
    //   The root of your project, i.e. where "package.json" lives. Default is '../..'
    // root = file("../../")
    //   The folder where the react-native NPM package is. Default is ../../node_modules/react-native
    // reactNativeDir = file("../../node_modules/react-native")
    //   The folder where the react-native Codegen package is. Default is ../../node_modules/@react-native/codegen
    // codegenDir = file("../../node_modules/@react-native/codegen")
    //   The cli.js file which is the React Native CLI entrypoint. Default is ../../node_modules/react-native/cli.js
    // cliFile = file("../../node_modules/react-native/cli.js")
    /* Variants */
    //   The list of variants to that are debuggable. For those we're going to
    //   skip the bundling of the JS bundle and the assets. Default is "debug", "debugOptimized".
    //   If you add flavors like lite, prod, etc. you'll have to list your debuggableVariants.
    // debuggableVariants = ["liteDebug", "liteDebugOptimized", "prodDebug", "prodDebugOptimized"]
    /* Bundling */
    //   A list containing the node command and its flags. Default is just 'node'.
    // nodeExecutableAndArgs = ["node"]
    //
    //   The command to run when bundling. By default is 'bundle'
    // bundleCommand = "ram-bundle"
    //
    //   The path to the CLI configuration file. Default is empty.
    // bundleConfig = file(../rn-cli.config.js)
    //
    //   The name of the generated asset file containing your JS bundle
    // bundleAssetName = "MyApplication.android.bundle"
    //
    //   The entry file for bundle generation. Default is 'index.android.js' or 'index.js'
    // entryFile = file("../js/MyApplication.android.js")
    //
    //   A list of extra flags to pass to the 'bundle' commands.
    //   See https://github.com/react-native-community/cli/blob/main/docs/commands.md#bundle
    // extraPackagerArgs = []
    /* Hermes Commands */
    //   The hermes compiler command to run. By default it is 'hermesc'
    // hermesCommand = "$rootDir/my-custom-hermesc/bin/hermesc"
    //
    //   The list of flags to pass to the Hermes compiler. By default is "-O", "-output-source-map"
    // hermesFlags = ["-O", "-output-source-map"]

    /* Autolinking */
    autolinkLibrariesWithApp()
}

/**
 * Set this to true to run Proguard on Release builds to minify the Java bytecode.
 */
def enableProguardInReleaseBuilds = true

/**
 * The preferred build flavor of JavaScriptCore (JSC).
 *
 * For example, to use the international variant, you can use:
 * `def jscFlavor = 'org.webkit:android-jsc-intl:+'`
 *
 * The international variant includes ICU i18n library and necessary data
 * allowing to use e.g. `Date.toLocaleString` and `String.localeCompare` that
 * give correct results when using with locales other than en-US.  Note that
 * this variant is about 6MiB larger per architecture than default.
 */
// def jscFlavor = 'org.webkit:android-jsc-intl:+'

android {
    ndkVersion rootProject.ext.ndkVersion
    buildToolsVersion rootProject.ext.buildToolsVersion
    compileSdk rootProject.ext.compileSdkVersion

    namespace "app.upryzing.clerotri"
    defaultConfig {
        applicationId "app.upryzing.clerotri"
        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.targetSdkVersion
        versionCode 22
        versionName "0.14.1"

        // disable build-time UUIDs (see https://gitlab.com/IzzyOnDroid/repo/-/wikis/Reproducible-Builds/RB-Hints-for-Developers#no-funny-build-time-generated-ids)
        externalNativeBuild {
            cmake {
                arguments "-DCMAKE_SHARED_LINKER_FLAGS=-Wl,--build-id=none"
            }
            ndkBuild {
                arguments "APP_LDFLAGS+=-Wl,--build-id=none"
            }
        }
    }

    // Detect app bundle and conditionally disable split ABIs
    // This is needed due to a "Sequence contains more than one matching element" error
    // present since AGP 8.9.0 - for more info, see:
    // https://issuetracker.google.com/issues/402800800

    // AppBundle tasks usually contain "bundle" in their name
    def isBuildingBundle = project.gradle.startParameter.taskNames.contains("app:buildApksRelease")
    
    splits {
        abi {
            // Disable split abis when building appBundle
            enable !isBuildingBundle
            reset()
            universalApk false
            include "armeabi-v7a", "arm64-v8a", "x86", "x86_64"
        }
    }

    signingConfigs {
        debug {
            storeFile file('debug.keystore')
            storePassword 'android'
            keyAlias 'androiddebugkey'
            keyPassword 'android'
        }
        release {
            if (project.hasProperty('CLEROTRI_UPLOAD_STORE_FILE')) {
                storeFile file(CLEROTRI_UPLOAD_STORE_FILE)
                storePassword CLEROTRI_UPLOAD_STORE_PASSWORD
                keyAlias CLEROTRI_UPLOAD_KEY_ALIAS
                keyPassword CLEROTRI_UPLOAD_KEY_PASSWORD
            } else {
                storeFile file('debug.keystore')
                storePassword 'android'
                keyAlias 'androiddebugkey'
                keyPassword 'android'
            }
        }
    }

    bundletool {
        signingConfig {
            if (project.hasProperty('CLEROTRI_UPLOAD_STORE_FILE')) {
                storeFile = file(CLEROTRI_UPLOAD_STORE_FILE)
                storePassword = CLEROTRI_UPLOAD_STORE_PASSWORD
                keyAlias = CLEROTRI_UPLOAD_KEY_ALIAS
                keyPassword = CLEROTRI_UPLOAD_KEY_PASSWORD
            }
        }
    }

    buildTypes {
        debug {
            signingConfig signingConfigs.debug
            applicationIdSuffix '.debug'
            versionNameSuffix '-debug'
        }
        release {
            signingConfig signingConfigs.release
            minifyEnabled enableProguardInReleaseBuilds
            shrinkResources enableProguardInReleaseBuilds
            proguardFiles getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro"
        }
    }

    // this is removed as it's only useable by Google
    dependenciesInfo {
        // Disables dependency metadata when building APKs.
        includeInApk = false
        // Disables dependency metadata when building Android App Bundles.
        includeInBundle = false
    }

}

dependencies {
    // The version of react-native is set by the React Native Gradle Plugin
    implementation("com.facebook.react:react-android")
    
    // if (hermesEnabled.toBoolean()) {
        implementation("com.facebook.react:hermes-android")
    // } else {
    //    implementation jscFlavor
    // }

    implementation('androidx.exifinterface:exifinterface:1.3.7')
}

// we don't want the React plugin to bundle - this is rnx-kit's job
tasks.whenTaskAdded { task ->
    // the task name can be found in `react-native-gradle-plugin`:
    // https://github.com/facebook/react-native/blob/0.77-stable/packages/gradle-plugin/react-native-gradle-plugin/src/main/kotlin/com/facebook/react/TaskConfiguration.kt#L54
    if (task.name.startsWith("createBundle") && task.name.endsWith("JsAndAssets")) {
        task.enabled = false
    }
}